ActionScript 3.0 features a full implementation of ECMAScript for XML (E4X), recently standardized as ECMA-357. E4X offers a natural, fluent set of language constructs for manipulating XML. Unlike traditional XML parsing API’s, E4X makes XML feel like a native data type of the language. E4X streamlines the development of applications that manipulate XML by drastically reducing the amount of code needed. You can learn more about the E4X specification here:

http://www.ecma-international.org/publications/files/ECMA-ST/ECMA-357.pdf

package
{
import flash.display.MovieClip;
import flash.util.trace;
 
public class E4XExample extends MovieClip
{
	public function E4XExample()
	{
		var employees:XML =
		<staff>
		 <employee id="1" status="active">
		 <name>Christian Cantrell</name>
		 <position>CEO</position>
		 <startDate>12/1/2001</startDate>
		 </employee>
		<employee id="2" status="active">
		  <name>Danny Dura</name>
		  <position>Developer</position>
		  <startDate>4/9/2003</startDate>
	         </employee>
		<employee id="3" status="contractor">
		  <name>Mike Chambers</name>
		  <position>Director</position>
		  <startDate>8/11/1999</startDate>
		</employee>
		<employee id="4" status="active">
		  <name>Scott Fegette</name>
		  <position>President</position>
		  <startDate>2/4/1889</startDate>
		</employee>
		</staff>
			
	//All employees\' names (as an XMLList)
	trace(employees.employee.name);
			
	// The first employee\'s name
	// Christian
	trace(employees.employee[0].name);
 
	// All IDs (as an XMLList)
	// 1234
	trace(employees.employee.@id);
			
	// The name of the employee with an ID of 2
	// Danny Dura
	trace(employees.employee.(@id==2).name);
			
	// The employee with the name "Christian Cantrell"
	// Returns an XMLList
	trace(employees.employee.(name == "Christian Cantrell"));
 
	// Employee #3\'s start date
	// 8/11/1999
	trace(employees.employee.(@id==3).startDate);
 
	// All contractors (as XMLList)
	trace(employees.employee.(@status=="contractor"));
 
	// All contractors\' names (as XMLList)
	trace(employees.employee.(@status=="contractor").name);
 
	// All employees with IDs less than or equal to 2
	// Returns an XMLList
	trace(employees.employee.(@id <= 2));
 
	// Iterate through all start dates
	var item:XML;
	for each (item in employees..startDate)
	{
	   trace(item);
	}
	}
}
}